//Name of Beeruser ;)
name="JOEL";

//Font name
fontname="Arial"; //[Vivian,Holtwood One SC,Alegreya Sans SC Black,Alfa Slab One,Asset,Black Ops One,Bowlby One,Bowlby One SC,Chango,Cinzel Decorative Black,Coustard,Elsie Black,Elsie Swash Caps Black,Erica One,Exo2 Black,Fascinate,Lobster,PassionOne,Plaster,Poller One,Rammetto One,Ruslan Display,Sarpanch Black,Sigmar One,Sonsie One,Titan One,Ultra,Hanalei]

//Height of clip
hoehe = 3;

//Inner radius. Fits for European Beer-Bottles
radius_innen = 12;

//Font height
schrift_hoehe = 9;

//-------------------------------------------------------------------------------

module beerClip()
{
  staerke = 2.5;
  schrift_unterschneidung = 0.75;
  schlitz_breite = 3;
  schlitz_hoehe = 9;
  cut=15;
  
  radius_aussen = radius_innen + staerke;
  difference() {
    difference() {
      cylinder(r = radius_aussen, h = hoehe, center = true);
      cylinder(r = radius_innen, h = hoehe, center = true);
    }
    translate([0,cut,0]) 
      cube([50, 20, hoehe], center = true);
    }
  rotate([180,0,0])
  
    for (r=[0:len(name)-1]){
      rotate(20+r*160/(len(name)-1),[0,0,1])
        translate([radius_aussen-schrift_unterschneidung,0,0])
          rotate(-90,[0,0,1])
            translate([0,0,-hoehe/2])
              linear_extrude(hoehe)
                text(name[len(name)-r-1],size=10,font=fontname,halign="center",valign="baseline");

    }
    translate([18,cut/2 -1 ,0])
      difference() {
        cube([schlitz_hoehe+staerke, 2*staerke+schlitz_breite, hoehe], center = true);
        translate([-staerke/2,0,0])
        cube([schlitz_hoehe, schlitz_breite, hoehe], center = true);
      }
}

beerClip();